CardReaderManager.idl

/* SPDX-License-Identifier: BSD-3-Clause */
/*
 * Copyright 2013 Raritan Inc. All rights reserved.
 */
 
#ifndef __SMARTCARD_CARD_READER_MANAGER_IDL__
#define __SMARTCARD_CARD_READER_MANAGER_IDL__
 
#include <CardReader.idl>
#include <Event.idl>
#include <UserEvent.idl>
 
/** Card Reader Manager */
module smartcard {
 
    /** Card Reader Manager Interface */
    interface CardReaderManager {
 
        /**
         * Card Reader Settings
         */
        [sparse_in]
        structure CardReaderSettings {
            string name;                ///< User-defined name
            string description;         ///< User-defined description
            string cardFormat;          ///< Card format, must be one of the values returned by
                                        ///< getSupportedCardFormats(); use "RAW" for plain
                                        ///< hexadecimal representation.
        };
 
        /**
         * Card Reader base event
         */
        valueobject CardReaderEvent extends idl.Event {
            CardReader cardReader;        ///< Affected card reader
            CardReader.MetaData metaData; ///< Metadata of affected card reader
        };
 
        /**
         * Card Reader attached event
         */
        valueobject CardReaderAttachedEvent extends CardReaderEvent {};
 
        /**
         * Card Reader detached event
         */
        valueobject CardReaderDetachedEvent extends CardReaderEvent {};
 
        /*
         * Event: A card reader's settings have been changed
         */
        valueobject CardReaderSettingsChangedEvent extends event.UserEvent {
            CardReader cardReader;        ///< affected card reader
            CardReaderSettings oldSettings;     ///< Settings before change
            CardReaderSettings newSettings;     ///< Settings after change
            string position;                    ///< Position of the card reader (see CardReader.MetaData)
        };
 
        /**
         * Retrieve the list of connected card readers.
         *
         * @return Card Readers list
         */
        vector<CardReader> getCardReaders();
 
        /**
         * Get card reader for a specific id.
         *
         * @param  readerId     card reader id
         *
         * @return Card Reader with given id or null
         */
        CardReader getCardReaderById(in string readerId);
 
        /**
         * Set settings for a card reader.
         *
         * @param position      position of card reader (see CardReader.MetaData)
         * @param settings      new settings for card reader
         *
         * @return NO_ERROR                     if OK
         * @return ERR_INVALID_PARAMS           if any setting is invalid
         *
         * @note The CardReaderSettings structure can be "sparse"; fields missing
         *       in the JSON representation will remain unchanged.
         */
        int setCardReaderSettings(in string position, in CardReaderSettings setting);
 
        /**
         * Get settings for all card readers.
         *
         * @return Map of settings by card reader position (see CardReader.MetaData)
         */
        map<string, CardReaderSettings> getAllCardReaderSettings();
 
        /**
         * Retrieve the list of supported card formats like "RAW", "H10301", etc.
         *
         * @return Card Formats list
         */
        vector<string> getSupportedCardFormats();
    };
 
}
 
#endif /* __SMARTCARD_CARD_READER_MANAGER_IDL__ */