Inlet.idl

/* SPDX-License-Identifier: BSD-3-Clause */
/*
 * Copyright 2009 Raritan Inc. All rights reserved.
 */
 
#ifndef __PDUMODEL_INLET_IDL__
#define __PDUMODEL_INLET_IDL__
 
#include <EDevice.idl>
#include <Nameplate.idl>
#include <NumericSensor.idl>
#include <StateSensor.idl>
#include <Pole.idl>
#include <ResidualCurrentStateSensor.idl>
 
/**
 * PDU Model
 */
module pdumodel {
 
    /** %Inlet interface */
    interface Inlet extends EDevice {
 
        /** %Inlet metadata */
        structure MetaData {
            string label;                       ///< %Inlet label
            string plugType;                    ///< Plug type
            Nameplate namePlate;          ///< %Nameplate information
            Rating rating;                ///< Numerical usage ratings
            boolean hasWaveformSupport;         ///< Whether waveform reading is supported on this inlet
            boolean isDC;                       ///< Current type, \c true for DC, \c false for AC
        };
 
        /** %Inlet sensors */
        structure Sensors {
            sensors.NumericSensor voltage;             ///< RMS voltage sensor (may be a VoltageMonitoringSensor)
            sensors.NumericSensor current;             ///< RMS current sensor
            sensors.NumericSensor peakCurrent;         ///< Peak current sensor
            sensors.NumericSensor residualCurrent;     ///< Residual current sensor
            sensors.NumericSensor residualACCurrent;   ///< AC Residual current sensor
                                                             ///< (AC portion of residual operating current)
            sensors.NumericSensor residualDCCurrent;   ///< DC Residual current sensor
                                                             ///< (DC portion of residual operating current)
            sensors.NumericSensor activePower;         ///< Active power sensor
            sensors.NumericSensor reactivePower;       ///< Reactive power sensor
            sensors.NumericSensor apparentPower;     ///< Apparent power sensor
            sensors.NumericSensor powerFactor;         ///< Power factor sensor
            sensors.NumericSensor displacementPowerFactor; ///< Displacement power factor sensor
            sensors.NumericSensor activeEnergy;        ///< Active energy sensor
            sensors.NumericSensor apparentEnergy;    ///< Apparent energy sensor
            sensors.NumericSensor unbalancedCurrent; ///< Current unbalance sensor
            sensors.NumericSensor unbalancedLineLineCurrent; ///< Line-Line current unbalance sensor
            sensors.NumericSensor unbalancedVoltage; ///< Voltage unbalance sensor
            sensors.NumericSensor unbalancedLineLineVoltage; ///< Line-Line voltage unbalance sensor
            sensors.NumericSensor lineFrequency;     ///< Line AC frequency sensor
            sensors.NumericSensor phaseAngle;        ///< Phase angle sensor
            sensors.NumericSensor crestFactor;        ///< Crest factor sensor
            sensors.NumericSensor voltageThd;         ///< Voltage total harmonic distortion sensor
            sensors.NumericSensor currentThd;         ///< Current total harmonic distortion sensor
            sensors.StateSensor powerQuality;        ///< Power quality sensor
            sensors.StateSensor surgeProtectorStatus;  ///< Surge protector status sensor
            ResidualCurrentStateSensor residualCurrentStatus; ///< Residual current monitor state sensor
        };
 
        /** %Inlet settings */
        structure Settings {
            string name;                        ///< User-defined name
        };
 
        /** Event: Inlet settings have been changed */
        valueobject SettingsChangedEvent extends event.UserEvent {
            Settings oldSettings;               ///< Settings before change
            Settings newSettings;               ///< Settings after change
        };
 
        /** Event: Inlet has been enabled or disabled */
        valueobject EnableStateChangedEvent extends event.UserEvent {
            boolean enabled;                    ///< New enable state
        };
 
        /**
         * Retrieve the inlet metadata.
         *
         * @return %Inlet metadata
         */
        MetaData getMetaData();
 
        /**
         * Get the inlet sensors.
         *
         * @return %Inlet sensors
         */
        Sensors getSensors();
 
        /**
         * Get the list of inlet poles.
         *
         * @return List of inlet poles
         */
        vector<Pole> getPoles();
 
        /**
         * Get the list of inlet line pairs.
         *
         * @return List of inlet line pairs
         */
        vector<MeteredLinePair> getLinePairs();
 
        /**
         * Retrieve the inlet settings.
         *
         * @return %Inlet settings
         */
        Settings getSettings();
 
        /**
         * Change the inlet settings.
         *
         * @param settings  New inlet settings
         *
         * @return 0 if OK
         * @return 1 if any parameters are invalid
         */
        int setSettings(in Settings settings);
 
        /**
         * Enable/disable PDU operation for this inlet.
         *
         * When PDU operation is disabled the sensors for this inlet and all
         * children will no longer be updated, and outlet switching is no
         * longer allowed. This can be useful for multi-inlet units if one
         * inlet is temporarily expected to be powered down.
         *
         * @param enabled  \c true to enable PDU operation
         */
        void setEnabled(in boolean enabled);
 
        /**
         * Test whether PDU operation is enabled for this inlet.
         *
         * @return \c true if PDU operation is enabled
         */
        boolean isEnabled();
    };
 
}
 
#endif