DsamPort.idl

/* SPDX-License-Identifier: BSD-3-Clause */
/*
 * Copyright 2022 Raritan Inc. All rights reserved.
 */
 
#ifndef __DSAMPORT_IDL__
#define __DSAMPORT_IDL__
 
#include <UserEvent.idl>
 
module dsam {
 
    /** DSAM port interface */
    interface DsamPort {
 
        /** Success code */
        constant int SUCCESS = 0;
 
        /** Error codes */
        constant int SETTINGS_INVALID = 1;
        constant int SSH_DPA_PORT_INVALID = 2;
        constant int SSH_DPA_PORT_IN_USE = 3;
 
        /** Serial device interface type */
        enumeration DeviceInterfaceType {
            DEV_IFTYPE_AUTO,                    ///< auto detect
            DEV_IFTYPE_DTE,                     ///< DTE (Data Terminal Equipment) device detected
            DEV_IFTYPE_DCE                      ///< DCE (Data Communications Equipment) device detected
        };
 
        /** Parity mode */
        enumeration Parity {
            PARITY_NONE,                        ///< No parity (implies 8 data bits)
            PARITY_ODD,                         ///< Odd parity (implies 7 data bits)
            PARITY_EVEN                         ///< Even parity (implies 7 data bits)
        };
 
        /** Flow control type */
        enumeration FlowControl {
            FLOW_CTRL_NONE,                     ///< No flow control
            FLOW_CTRL_HARDWARE,                 ///< Hardware flow control
            FLOW_CTRL_SOFTWARE                  ///< Software flow control
        };
 
        /** Port state */
        enumeration State {
            STATE_AVAILABLE,                    ///< no clients connected to port
            STATE_OCCUPIED,                     ///< at least one client connected, more clients allowed
            STATE_BUSY                          ///< no more clients allowed
        };
 
        /** Port info */
        structure Info {
            int dsamNumber;                     ///< DSAM number (1-based)
            int portNumber;                     ///< port number (1-based)
            boolean connected;                  ///< \c true if serial device is connected
            DeviceInterfaceType devIfType;      ///< serial device interface type if \c connected is \c true
            State state;                        ///< state of the port
        };
 
        /** Port settings */
        structure Settings {
            string name;                        ///< Port name
            DeviceInterfaceType devIfType;      ///< Port interface type (allows forcing the interface type)
            int baudRate;                       ///< Baud rate
            Parity parity;                      ///< Parity mode
            int stopBits;                       ///< Number of stop bits (1 or 2)
            FlowControl flowCtrl;               ///< Flow control type
            int breakDurationMs;                ///< Length of BREAK signal duration in milli seconds
            boolean sshDpaPortEnabled;          ///< \c true if dedicated SSH DPA port is enabled
            int sshDpaPort;                     ///< SSH DPA port number
            boolean allowSharedAccess;          ///< Allow more than one user to connect to this port
        };
 
        /** Event that is send when the port info has changed */
        valueobject InfoChangedEvent extends event.UserEvent {
            Info oldInfo;                       ///< Old port info
            Info newInfo;                       ///< New port info
            string portName;                    ///< current port name
        };
 
        /** Event that is send whenthe port settings have changed */
        valueobject SettingsChangedEvent extends event.UserEvent {
            int dsamNumber;                     ///< DSAM number
            int portNumber;                     ///< port number
            Settings oldSettings;               ///< Old port settings
            Settings newSettings;               ///< New port settings
        };
 
        /**
         * Get current port info.
         *
         * @return Port info
         */
        Info getInfo();
 
        /**
         * Get current port settings.
         *
         * @return  Port settings.
         */
        Settings getSettings();
 
        /**
         * Set port settings.
         *
         * @param settings  Port settings
         * @return SUCCESS if no error occured or one of the defined error codes
         */
        int setSettings(in Settings settings);
 
        /**
         * Get the number of the ttyUSB device.
         *
         * NOTE: This function is only used internally and is not available via JSON-RPC.
         *
         * @return ttyUSB device number
         */
        int getTtyUsbNumber();
 
        /**
         * Set the state of the port.
         *
         * NOTE: This function is only used internally and is not available via JSON-RPC.
         *
         * @param state  Port state
         */
        void setState(in State state);
    };
}
 
#endif // __DSAM_PORT__