VoltageMonitoringSensor.idl

/* SPDX-License-Identifier: BSD-3-Clause */
/*
 * Copyright 2020 Raritan Inc. All rights reserved.
 */
 
#ifndef __PDUMODEL_VOLTAGE_MONITORING_SENSOR_IDL__
#define __PDUMODEL_VOLTAGE_MONITORING_SENSOR_IDL__
 
#include <NumericSensor.idl>
#include <UserEvent.idl>
#include <Waveform.idl>
 
/**
 * PDU Model
 */
module pdumodel {
 
    /** Interface of a voltage sensor with extended monitoring capabilities */
    interface VoltageMonitoringSensor extends sensors.NumericSensor {
        [unknown_fallback("UNKNOWN")]
        enumeration EventType {
            DIP,
            SWELL,
            UNKNOWN
        };
 
        structure DipSwellThresholds {
            boolean dipActive;              ///< \c true if dip events should be monitored
            double  dipThreshold;           ///< Dip event threshold
            boolean swellActive;            ///< \c true if swell events should be monitored
            double  swellThreshold;         ///< Swell event threshold
            float   deassertionHysteresis;  ///< Deassertion hysteresis
        };
 
        /** Definition of a voltage fluctuation event observed by this sensor */
        structure Event {
            EventType type;     ///< Type of event
            time timestamp;     ///< Time of event occurrence
            int duration;       ///< Event duration in milliseconds
            double voltage;     ///< Voltage level observed during the event:
                                ///<   - for dip events: lowest voltage observed
                                ///<   - for swell events: highest voltage observed
            Waveform waveform;  ///< Waveform of event
        };
 
        /** Event: A new dip/swell event occurred */
        valueobject EventOccurredEvent extends idl.Event {
            Event event;    ///< Event that was observed
        };
 
        /** Event: The list of observed events was cleared */
        valueobject EventListClearedEvent extends event.UserEvent {
        };
 
        /** Event: Dip/swell thresholds were changed */
        valueobject DipSwellThresholdsChangedEvent extends event.UserEvent {
            DipSwellThresholds oldThresholds;
            DipSwellThresholds newThresholds;
        };
 
        /** Get all events that were observed so far, ordered from
         *  most recent to least recent event.
         *  Note: The response might be limited to a certain number of records.
         */
        vector<Event> getRecentEvents();
 
        /** Clear list of observed events. */
        void clearRecentEvents();
 
        /**
         * Retrieve the dip/swell thresholds.
         *
         * @return Set of thresholds
         */
        DipSwellThresholds getDipSwellThresholds();
 
        /**
         * Change the dip/swell thresholds.
         *
         * @param thresholds  New set of thresholds
         *
         * @return 0                        if OK
         * @return THRESHOLD_OUT_OF_RANGE   if any threshold is out of range
         * @return THRESHOLD_INVALID        if thresholds don't meet the requirements
         */
        int setDipSwellThresholds(in DipSwellThresholds thresholds);
    };
}
 
#endif